Outlook: Standardformatierung für E-Mails einstellen (Größe und Art der Schrift etc.)

Beim Senden einer E-Mail in Outlook (egal ob neue Nachricht, Antwort oder Weiterleitung) führt der Mailclient oft ungewollte Änderungen an der Schriftart und Schriftgröße, dem Zeilenabstand etc. durch. Er richtet sich dabei nach der Formatierung der letzten E-Mail oder nach der Standardformatierung. Das Problem betrifft insbesondere die Absatzeinstellungen.

In MS Word und anderen Schreibprogrammen drückt man auf die Eingabe-Taste, um einen neuen Absatz zu beginnen. Für eine neue Zeile drückt man gleichzeitig auf Umschalt + Eingabe. In Outlook ist das kein Unterschied. Egal ob man die Eingabe oder Umschalt + Eingabe drückt, es wird eine neue Zeile erstellt. Für einen Absatz muss der Anwender 2x die Taste drücken. Es führt dazu, dass der Text je nach Mailclient unterschiedlich dargestellt wird.

Anstatt die Eingabe-Taste zweimal zu drücken, kann man die Standardformatierung, also den normalen Stil in Outlook anpassen. Der Nachteil ist, dass der normale Stil nur für neue Nachrichten, also nicht für Antworten und Weiterleitungen, angewendet wird.

Ein anderer möglicher Ansatz wäre, einen benutzerdefinierten Stil zu hinterlegen, welcher im Gegensatz zu dem normalen Stil auch für Antworten und Weiterleitungen greift. Auch diese Lösung hat eine Schwachstelle, denn der neue Stil wird nicht als Standard festgelegt, sondern muss beim Öffnen des E-Mail-Fensters jedes Mal neu ausgewählt werden.

Die vollständige Lösung ist also ein benutzerdefinierter Stil, welcher durch ein Outlook-Makro als Standard gesetzt wird und sowohl für neue E-Mails als auch für Antworten / Weiterleitungen greift. Nachfolgend finden Sie eine detaillierte Anleitung für die Config.

Zunächst definieren Sie Ihren Stil. Dafür erstellen Sie in Outlook eine neue E-Mail und tippen Sie ein paar Worte ein. Markieren Sie Ihren Text und in dem eingeblendeten Menü gehen Sie auf Styles, Create a style.

Es wird ein Fenster geöffnet, wo Sie Ihren Stil benennen können, z.B. Custom Style 1. Anschließend gehen Sie auf Modify, um die Formatierung anzupassen. Nachstehend finden Sie einen Screenshot mit allen Einstellungen, die greifen sollen. In aller Kürze sind es:

• Die Option Style based on muss auf (no style) eingestellt werden
• Unter Formatting definieren Sie die Schriftart und Schriftgröße, z.B. Arial, 11
• Die Option New documents based on this template muss eingecheckt werden
• Klicken Sie auf den Button Format und öffnen Sie das Fenster Paragraph. Unter Spacing setzen Sie den Wert After auf 12 pt, Line spacing auf At least und den Wert At auf 14 pt.

Alle Änderungen bestätigen Sie mit OK, um zu Ihrer E-Mail zurückzugelangen. Senden Sie sie an sich selbst oder an eine andere E-Mail-Adresse. Dasselbe tun Sie für Antworten und Weiterleitungen. Zum Schluss testen Sie Ihren neuen Stil an unterschiedlichen Nachrichten, insbesondere an jenen, die von anderen Anwendern kommen.

Mit einem Makro legen Sie Ihren benutzerdefinierten Stil als Standard fest. Tun Sie Folgendes:

1. In der Multifunktionsleiste gehen Sie zum Tab Developer.
2. Klicken Sie auf Macro Security, Enable all macros.
3. Klicken Sie auf den Button Visual Basic. Im VB-Fenster gehen Sie auf Tools, References.

Stellen Sie sicher, dass in der Liste Available References folgende Optionen vorhanden sind:

• Visual Basic For Applications
• Microsoft Outlook 15.0 Object Library
• OLE Automation
• Microsoft Office 15.0 Object Library
• Microsoft DAO 3.6 Object Library
• Microsoft Word 15.0 Object Library

WICHTIG: Einige Bibliotheken werden mit Versionsnummer angezeigt, welche von der Version Ihrer MS Office-Suite abhängt. Für MS Office 2013 ist das die Version 15.0, für Office 2010 die 14.0, und für Office 2007 die 12.0. Die Microsoft DAO Object Library ist gleich für alle Office-Suiten.

4. Wenn alle Referenzen vorhanden sind, klicken Sie auf den Button OK.
5. Bleiben Sie in Visual Basic und öffnen Sie das Projektfenster, indem Sie das Projektverzeichnis links ausrollen und 2x auf ThisOutlookSession klicken:

6. In das eingeblendete Fenster fügen Sie diesen Makro-Code ein:

Public WithEvents OutlookInspectors As Outlook.Inspectors
Public WithEvents myOlExp As Outlook.Explorer
Public WithEvents myIns As Outlook.Inspector

'startup Outlook
Private Sub Application_Startup()
    Set OutlookInspectors = Application.Inspectors
    Set myOlExp = Application.ActiveExplorer
End Sub
    
Private Sub OutlookInspectors_NewInspector(ByVal Inspector As Inspector)
    Set myIns = Inspector
End Sub

Private Sub myOlExp_InlineResponse(ByVal item As Object)

'Change the name of the style to your own
'The name is case sensitive
Dim objStyleName As String
objStyleName = "Custom Style 1"

    Dim objEditor As Word.Document
    Dim objStyle As Word.Style
    'Check if the message is Plain Text. If so - end the macro as Plain Text does not support styles
    'Bodyformat:
    '1 - plain text
    '2 - html
    '3 - rtf
    If ActiveExplorer.ActiveInlineResponse.BodyFormat = 1 Then Exit Sub
    Set objEditor = ActiveExplorer.ActiveInlineResponseWordEditor
    Set objStyle = objEditor.Styles.item(objStyleName)
    
    'No need to set the same style again - it can break copy-paste option and duplicate text
    'If you have changed style to other than defined in objStyleName program can still duplicate text
    If objEditor.Windows(1).Selection.Style = objStyle Then Exit Sub
    objEditor.Windows(1).Selection.Style = objStyle
    
    Set objEditor = Nothing
    Set objStyle = Nothing
    
End Sub

Private Sub myIns_Activate()
'Change the name of the style to your own
'The name is case sensitive
Dim objStyleName As String
objStyleName = "Custom Style 1"

    If myIns.IsWordMail() = False Then Exit Sub
    Dim objEditor As Word.Document
    Dim objStyle As Word.Style
    Dim objItem As Object
    
    Set objItem = myIns.CurrentItem
    'Check if object is empty
    If objItem Is Nothing Then Exit Sub
    
    'Check the type of the item np. Meeting request
    Dim iStringPos As Integer
    iStringPos = InStr(objItem.MessageClass, "IPM.Note")
    If iStringPos = 0 Then Exit Sub
    'If the object is flagged as sent, it means this is the uneditable content
    If objItem.Sent = "True" Then Exit Sub
    
    'Check if the message is Plain Text. If so - end the macro as Plain Text does not support styles
    'Bodyformat:
    '1 - plain text
    '2 - html
    '3 - rtf
    If objItem.BodyFormat = 1 Then Exit Sub
    If myIns.EditorType = olEditorWord Then
       Set objEditor = myIns.WordEditor
       Set objStyle = objEditor.Styles.item(objStyleName)
       If objStyle Is Nothing Then Exit Sub
    
    'No need to set the same style again - it can break copy-paste option and duplicate text
    'If you have changed style to other than defined in objStyleName program can still duplicate text
    If objEditor.Windows(1).Selection.Style = objStyle Then Exit Sub
    objEditor.Windows(1).Selection.Style = objStyle
    End If
    
    Set objEditor = Nothing
    Set objStyle = Nothing
    Set objItem = Nothing

End Sub

Ändern Sie den Stilnamen wie in den Makro-Kommentaren beschrieben. In diesem Fall Custom Style 1.

7. Speichern Sie das Projekt, indem Sie auf das blaue Disketten-Symbol klicken, oder drücken Sie Strg + S.
8. Starten Sie Outlook neu.

Das war’s – von nun an wird Ihr Stil angewendet, jedes Mal wenn Sie in Outlook eine Nachricht verfassen. Das gilt auch für den Fall, dass Sie auf eine E-Mail mit abweichender Formatierung antworten. Auf diese Weise stellen Sie sicher, dass das Design Ihrer Korrespondenz immer gleich bleibt.